BLE Device to Device with Nano RP2040 Connect

Copy
1#include <ArduinoBLE.h>
2
3int buttonPin = 2;
4boolean ledSwitch;
5
6BLEService LEDService("19B10000-E8F2-537E-4F6C-D104768A1214"); // BLE LED Service
7// BLE LED Switch Characteristic - custom 128-bit UUID, read and writable by central
8BLEByteCharacteristic LEDCharacteristic("19B10001-E8F2-537E-4F6C-D104768A1214", BLERead | BLENotify | BLEWrite);
9void setup() {
10  Serial.begin(9600);
11  pinMode(buttonPin, INPUT_PULLUP);
12  // begin initialization
13  if (!BLE.begin()) {
14    Serial.println("starting Bluetooth® Low Energy failed!");
15  }
16  // set advertised local name and service UUID:
17  BLE.setLocalName("Button Device");
18  BLE.setAdvertisedService(LEDService);
19  // add the characteristic to the service
20  LEDService.addCharacteristic(LEDCharacteristic);
21  // add service
22  BLE.addService(LEDService);
23  // start advertising
24  BLE.advertise();
25  Serial.println("BLE LED Peripheral, waiting for connections....");
26}
27void loop() {
28  // listen for BLE peripherals to connect:
29  BLEDevice central = BLE.central();
30  // if a central is connected to peripheral:
31  if (central) {
32    Serial.print("Connected to central: ");
33    // print the central's MAC address:
34    Serial.println(central.address());
35    // while the central is still connected to peripheral:
36    while (central.connected()) {
37
38      int buttonState = digitalRead(buttonPin);
39
40      if (buttonState == LOW) {
41        ledSwitch = !ledSwitch;
42        delay(500);
43
44        if (ledSwitch) {
45          Serial.println("ON");
46          LEDCharacteristic.writeValue((byte)0x01);
47        }
48        else {
49          LEDCharacteristic.writeValue((byte)0x00);
50          Serial.println("OFF");
51        }
52      }
53    }
54    // when the central disconnects, print it out:
55    Serial.print(F("Disconnected from central: "));
56    Serial.println(central.address());
57  }
58}

Copy
1#include <ArduinoBLE.h>
2
3void setup() {
4  pinMode(LED_BUILTIN, OUTPUT);
5  Serial.begin(9600);
6  while (!Serial);
7  // initialize the BLE hardware
8  BLE.begin();
9  Serial.println("BLE Central - LED control");
10  // start scanning for Button Device BLE peripherals
11  BLE.scanForUuid("19b10000-e8f2-537e-4f6c-d104768a1214");
12}
13void loop() {
14  // check if a peripheral has been discovered
15  BLEDevice peripheral = BLE.available();
16  if (peripheral) {
17    // discovered a peripheral, print out address, local name, and advertised service
18    Serial.print("Found ");
19    Serial.print(peripheral.address());
20    Serial.print(" '");
21    Serial.print(peripheral.localName());
22    Serial.print("' ");
23    Serial.print(peripheral.advertisedServiceUuid());
24    Serial.println();
25    if (peripheral.localName().indexOf("Button Device") < 0) {
26      Serial.println("No 'Button Device' in name");
27      return;  // If the name doesn't have "Button Device" in it then ignore it
28    }
29    // stop scanning
30    BLE.stopScan();
31    controlLed(peripheral);
32    // peripheral disconnected, start scanning again
33    BLE.scanForUuid("19b10000-e8f2-537e-4f6c-d104768a1214");
34  }
35}
36void controlLed(BLEDevice peripheral) {
37  // connect to the peripheral
38  Serial.println("Connecting ...");
39  if (peripheral.connect()) {
40    Serial.println("Connected");
41  } else {
42    Serial.println("Failed to connect!");
43    return;
44  }
45  // discover peripheral attributes
46  Serial.println("Discovering attributes ...");
47  if (peripheral.discoverAttributes()) {
48    Serial.println("Attributes discovered");
49  } else {
50    Serial.println("Attribute discovery failed!");
51    peripheral.disconnect();
52    return;
53  }
54  // retrieve the LED characteristic
55  BLECharacteristic LEDCharacteristic = peripheral.characteristic("19b10001-e8f2-537e-4f6c-d104768a1214");
56  if (!LEDCharacteristic) {
57    Serial.println("Peripheral does not have LED characteristic!");
58    peripheral.disconnect();
59    return;
60  }
61  while (peripheral.connected()) {
62    // while the peripheral is connected
63    if (LEDCharacteristic.canRead()) {
64      byte value = LEDCharacteristic.read();
65      LEDCharacteristic.readValue(value);
66      //Serial.println(LEDCharacteristic.readValue(value));
67      if (value == 0x01) {
68        Serial.println("ON");
69        digitalWrite(LED_BUILTIN, HIGH);
70      }
71      else if (value == 0x00) {
72        digitalWrite(LED_BUILTIN, LOW);
73        Serial.println("OFF");
74      }
75    }
76    delay(500);
77  }
78  Serial.println("Peripheral disconnected");
79}